arch/pkg/de-p1st-xfce4/PKGBUILD

# Maintainer: Daniel Langbein <daniel@systemli.org>
_pkgname=xfce4
_reponame=arch
pkgname="de-p1st-$_pkgname"
pkgver=0.0.2
pkgrel=1
pkgdesc="XFCE4 with configuration"
arch=('any')
url="https://codeberg.org/privacy1st/${_reponame}"
license=('MIT')


depends=()

# ============== base, drivers and xorg ==============
depends+=(de-p1st-base-efi)
depends+=(de-p1st-gpu)
depends+=(xorg-meta)

# ============== XFCE4 ==============
#
# xfce4 group
# pacman -Sg xfce4 | sed 's|^xfce4 |depends+=(|; s|$|)|'
depends+=(xfce4-meta)
# some pkgs from xfce4-goodies group, except e.g.
# ristretto (image viewer)
# xfce4-artwork
# xfce4-time-out-plugin (take breaks)
# xfce4-timer-plugin
# xfce4-xkb-plugin (keyboard layouts)
depends+=(mousepad thunar-archive-plugin thunar-media-tags-plugin xfce4-genmon-plugin xfce4-notifyd xfce4-screensaver xfce4-screenshooter xfce4-weather-plugin xfce4-whiskermenu-plugin)
#
# thunar optional dependencies:
#   - gvfs: for trash support, mounting with udisk and remote
#           filesystems (e.g. webdav)
depends+=(gvfs)
# keyring/secrets
# ->  https://wiki.archlinux.org/index.php/GNOME/Keyring
depends+=(gnome-keyring libsecret)

# ============== display manager ==============
depends+=(sddm)

# ============== network, theme, keyboard ==============
#
# NetworkManager applet
depends+=(network-manager-applet)  # depends on networkmanager
#
# gtk and qt theme
depends+=(de-p1st-theme)
#
# x11 keyboard layouts (TODO: move this to xorg package)
depends+=(de-p1st-keyboard-x11)


makedepends=('git')

provides=()
conflicts=()
replaces=()
backup=()
options=()
install=
changelog=
source=("git+${url}.git")
noextract=()
sha256sums=('SKIP')

package() {
  cd "${_reponame}/pkg/${pkgname}"

  install -Dm0644 img/face.jpg "$pkgdir"/etc/skel/.face

  # === display manager ===
  install -Dm0644 systemd.preset "$pkgdir"/usr/lib/systemd/system-preset/20-"$pkgname".preset
  install -Dm0644 autologin.conf "$pkgdir"/etc/sddm.conf.d/autologin.conf
}