# Maintainer: Daniel Langbein <daniel@systemli.org>
_pkgname=sddm-theme-nordic
_reponame=arch
pkgname="de-p1st-$_pkgname"
pkgver=0.0.3
pkgrel=1
pkgdesc="sddm with Nordic theme"
arch=('any')
url="https://codeberg.org/privacy1st/${_reponame}"
license=('MIT')

depends=('sddm' 'sddm-nordic-theme-git')
# Without plasma-framework the following error occurs:
# Main.qml:28:1: module "org.kde.plasma.extras" is not installed
depends+=('plasma-framework')
# See TODO below
depends+=('holo' 'git')

makedepends=('git')
install='.install'
source=("git+${url}.git")
sha256sums=('SKIP')
provides=('de-p1st-sddm-theme')
conflicts=('de-p1st-sddm-theme')

package() {
  cd "${_reponame}/pkg/${pkgname}"

  install -Dm0644 p1st-theme.conf "$pkgdir"/etc/sddm.conf.d/p1st-theme.conf

  # TODO: Fix upstream? See AUR comment: https://aur.archlinux.org/pkgbase/nordic-kde-git/#comment-807577
  # Fix Nordic theme "Main.qml" -> Property "Battery" not found / missing
  install -Dm0544 Main.qml.holoscript "$pkgdir"/usr/share/holo/files/"$pkgname"/usr/share/sddm/themes/Nordic/Main.qml.holoscript
}
