# Maintainer: Daniel Langbein <daniel@systemli.org>
_pkgname=xfce4
_reponame=arch
pkgname="de-p1st-$_pkgname"
pkgver=0.0.15
pkgrel=1
pkgdesc="XFCE4 with configuration"
arch=('any')
url="https://codeberg.org/privacy1st/${_reponame}"
license=('MIT')
makedepends=('git')
install='.install'
source=("git+${url}.git")
sha256sums=('SKIP')


depends=()

# ============== base, drivers and xorg ==============
depends+=('de-p1st-base')
depends+=('de-p1st-gpu')
depends+=('xorg-meta')

# ============== XFCE4 ==============
#
# xfce4 group
# pacman -Sg xfce4 | sed 's|^xfce4 |depends+=(|; s|$|)|'
depends+=(xfce4-meta)
# some pkgs from xfce4-goodies group, except e.g.
# ristretto (image viewer)
# xfce4-artwork
# xfce4-time-out-plugin (take breaks)
# xfce4-timer-plugin
# xfce4-xkb-plugin (keyboard layouts)
depends+=(mousepad thunar-archive-plugin thunar-media-tags-plugin xfce4-genmon-plugin xfce4-notifyd xfce4-screensaver xfce4-screenshooter xfce4-weather-plugin xfce4-whiskermenu-plugin)
#
# thunar optional dependencies:
#   - gvfs: for trash support, mounting with udisk and remote
#           filesystems (e.g. webdav)
depends+=(gvfs)
# keyring/secrets
# ->  https://wiki.archlinux.org/index.php/GNOME/Keyring
depends+=(gnome-keyring libsecret)
#
# bluelight filter
depends+=(de-p1st-redshift)

# ============== display manager ==============
# sddm with autologin
depends+=(de-p1st-sddm-autologin)
# sddm themeing
depends+=(de-p1st-sddm-theme)

# ============== network, theme, keyboard ==============
#
# NetworkManager applet
depends+=(network-manager-applet)  # depends on networkmanager
#
# gtk and qt theme
depends+=(de-p1st-theme)
#
# x11 keyboard layouts
depends+=(de-p1st-keyboard-x11)


package() {
  cd "${_reponame}/pkg/${pkgname}"

  install -Dm0644 img/face.jpg      "$pkgdir"/etc/skel/.face

  # Adding a xml configuration to /etc/xdg/xfce4/xfconf/xfce-perchannel-xml/*.xml does not work.
  # (It will not be copied to ~/.config/xfce4/xfconf/xfce-perchannel-xml/*.xml)
  # Thus we place it in the skeleton for new users!

  # === higher screen resolution in a VM ===
  # config/xfce4/xfconf/xfce4-perchannel-xml/displays.xml
  # === desktop  ===
  # config/xfce4/xfconf/xfce4-perchannel-xml/xfce4-desktop.xml
  # === workspaces ===
  # config/xfce4/xfconf/xfce4-perchannel-xml/xfwm4.xml
  # === panel ===
  # config/xfce4/xfconf/xfce4-perchannel-xml/xfce4-panel.xml
  # config/xfce4/panel/launcher-8/16218680691.desktop
  #
  mkdir -p      "$pkgdir"/etc/skel/
  cp -ra config "$pkgdir"/etc/skel/.config

  # === display manager ===
  install -Dm0644 systemd.preset        "$pkgdir"/usr/lib/systemd/system-preset/20-"$pkgname".preset
  install -Dm0644 p1st-settings.conf    "$pkgdir"/etc/sddm.conf.d/p1st-settings.conf
}
